## `plot::cylindrical` -- generate plots in cylindrical coordinates

#### Introduction

`plot::cylindrical``([rho, phi, z], u = a..b, v = c..d)` represents a plot of the surface defined by (u, v) -> (rho(u,v); phi(u,v); z(u,v)) with (u,v) in [a,b] x [c,d] in the cylindrical coordinates rho, phi, z.

#### Call(s)

`plot::cylindrical([rho, phi, z], u = a..b, v = c..d <, option1, option2>...)`

#### Parameters

`rho, phi, z` | - | arithmetical expressions in `u` and `v`
`u, v` | - | identifiers
`a, b, c, d` | - | arithmetical expressions
`option1, option2, ...` | - | plot option(s) for three-dimensional graphical objects

#### Related Domains

`plot::Surface3d`

#### Related Functions

`plot`, `plot3d`, `plot::spherical`, `plot::polar`

#### Returns

a graphical object of the domain type `plot::Surface3d`.

#### Details

- Call `plot(...)` to display the result on the screen.
- The following relationship between cylindrical coordinates and Cartesian coordinates holds:

      x = rho*cos(phi), y = rho*sin(phi), z = z.

- The plot options `option1`, `option2`... must be valid plot options for three-dimensional graphical objects. See `plot::Surface3d` for details.

  Note that scene options are not allowed! You may give scene options as optional arguments for the function `plot`, or use `plot::Scene` to create an object representing a graphical scene.

#### Example 1

We define a three-dimensional surface in cylindrical coordinates:

    >> s:= plot::cylindrical(
         [1, u, v], u = -PI..PI,  v = -1..1, Grid = [20, 20]
       )

           plot::Surface3d([cos(u), sin(u), v], u = -PI..PI, v = -1..1)

and plot it on the screen:

    >> plot(s, Axes = Box)

#### Example 2

Here we illustrate how to combine multiple cylindrical plots into a single graphical scene. We start by creating the two objects representing the cylindrical plots:

    >> s1:= plot::cylindrical(
         [u, u, v], u = -PI..PI, v = -PI..PI,
         Grid = [30, 30], Color = [Height]
       );
       s2:= plot::cylindrical(
         [-u, u, v], u = -PI..PI, v = -2..2,
         Grid = [30, 30], Color = [Height]
       )

          plot::Surface3d([u cos(u), u sin(u), v], u = -PI..PI,

             v = -PI..PI)

          plot::Surface3d([-u cos(u), -u sin(u), v], u = -PI..PI,

             v = -2..2)

Then the next call plots these two objects in one graphical scene and sets the style of the axes to the value `Box`:

    >> plot(s1, s2, Axes = Box)

#### Changes

- used to be called `plotlib::cylindricalplot`
- `plot::cylindrical` is now part of the new plot library `plot`, and thus its calling syntax and the return value were changed.

Do you have questions or comments?
Copyright © SciFace Software GmbH & Co. KG 2000