CMAKE_MINIMUM_REQUIRED(VERSION 3.16)
project(dxirc-fox LANGUAGES CXX)
set(PROJECT_VERSION "1.50.0")

set(DXIRCFOX_LIBS "")
set(DXIRCFOX_INCLUDE_DIRS "")

if(APPLE)
    set(FOX_HAVE_TRAY FALSE)
else(APPLE)
    option(FOX_HAVE_TRAY "Enable trayicon" TRUE)
endif(APPLE)
option(FOX_ENABLE_IPV6 "Enable IPv6 support" TRUE)

list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")

if(PKG_CONFIG_FOUND)
    pkg_check_modules(FOX fox)
    list(APPEND DXIRCFOX_LIBS ${FOX_LIBRARIES})
    list(APPEND DXIRCFOX_INCLUDE_DIRS ${FOX_INCLUDE_DIRS})
endif(PKG_CONFIG_FOUND)

if(NOT FOX_FOUND)
    set(FOX_INCLUDE_DIR "" CACHE PATH "Path to fox include dir")
    set(FOX_LIBRARY "" CACHE FILEPATH "Filepath to fox library")
    set(PNG_INCLUDE_DIR "" CACHE PATH "Path to png include dir")
    set(PNG_LIBRARY "" CACHE FILEPATH "Filepath to png library")
    if(FOX_INCLUDE_DIR AND PNG_INCLUDE_DIR)
        set(FOX_FOUND true)
        list(APPEND DXIRCFOX_LIBS ${FOX_LIBRARY} ${PNG_LIBRARY})
        list(APPEND DXIRCFOX_INCLUDE_DIRS ${FOX_INCLUDE_DIR} ${PNG_INCLUDE_DIR})
    endif()
endif()

if(NOT FOX_FOUND)
    message(FATAL_ERROR "Fox library not found. Can't build dxirc")
endif()

# Windows: MSYS2 links FOX as dll (libFOX-1.6.dll.a), MXE static target links libFOX-1.6.a
set(FOX_STATIC FALSE)
if(WIN32)
    find_library(FOX_LIBRARY_FILE NAMES FOX-1.6 HINTS ${FOX_LIBRARY_DIRS} ${FOX_STATIC_LIBRARY_DIRS})
    if(FOX_LIBRARY_FILE MATCHES "\\.a$" AND NOT FOX_LIBRARY_FILE MATCHES "\\.dll\\.a$")
        set(FOX_STATIC TRUE)
    endif()
endif(WIN32)

if(ENABLE_NLS)
    list(APPEND DXIRCFOX_LIBS ${LIBINTL_LIBRARIES})
    list(APPEND DXIRCFOX_INCLUDE_DIRS ${LIBINTL_INCLUDE_DIR})
    if(WIN32 AND FOX_STATIC)
        # static libintl needs libiconv
        find_library(ICONV_LIBRARY NAMES iconv)
        if(ICONV_LIBRARY)
            list(APPEND DXIRCFOX_LIBS ${ICONV_LIBRARY})
        endif()
    endif()
endif()

set(HAVE_X11 FALSE)
if(NOT WIN32)
    if(PKG_CONFIG_FOUND)
        pkg_check_modules(X11 x11)
        list(APPEND DXIRCFOX_LIBS ${X11_LIBRARIES})
        list(APPEND DXIRCFOX_INCLUDE_DIRS ${X11_INCLUDE_DIRS})
        if(X11_FOUND)
            set(HAVE_X11 TRUE)
        else(X11_FOUND)
            set(FOX_HAVE_TRAY FALSE)
        endif(X11_FOUND)
    endif(PKG_CONFIG_FOUND)
else(NOT WIN32)
    list(APPEND DXIRCFOX_LIBS "ws2_32" "winmm")
endif(NOT WIN32)

if(NOT WIN32)
    if(PKG_CONFIG_FOUND)
        pkg_check_modules(XFT xft fontconfig)
        list(APPEND DXIRCFOX_LIBS ${XFT_LIBRARIES})
        list(APPEND DXIRCFOX_INCLUDE_DIRS ${XFT_INCLUDE_DIRS})
        if(XFT_FOUND)
            add_definitions(-DHAVE_XFT_H)
        endif(XFT_FOUND)
    endif(PKG_CONFIG_FOUND)
endif(NOT WIN32)

# StatusNotifierItem tray icon on Linux
set(HAVE_DBUS FALSE)
if(FOX_HAVE_TRAY AND NOT WIN32 AND NOT APPLE AND PKG_CONFIG_FOUND)
    pkg_check_modules(DBUS dbus-1)
    if(DBUS_FOUND)
        list(APPEND DXIRCFOX_LIBS ${DBUS_LIBRARIES})
        list(APPEND DXIRCFOX_INCLUDE_DIRS ${DBUS_INCLUDE_DIRS})
        set(HAVE_DBUS TRUE)
    endif(DBUS_FOUND)
endif()

set(HAVE_OPENSSL FALSE)
find_package(OpenSSL)
if(OPENSSL_FOUND)
    if(WIN32)
        # On windows/mingw we need libeay32 too...
        find_library(LIB_EAY NAMES libeay32MD eay libeay libeay32)
        if(LIB_EAY)
            list(APPEND DXIRCFOX_INCLUDE_DIRS ${OPENSSL_INCLUDE_DIR})
            list(APPEND DXIRCFOX_LIBS ${OPENSSL_LIBRARIES} ${LIB_EAY})
            # Windows crypto API: static OpenSSL, system root certificates (dxSocket)
            list(APPEND DXIRCFOX_LIBS crypt32)
            set(HAVE_OPENSSL TRUE)
        endif()
    else()
        list(APPEND DXIRCFOX_INCLUDE_DIRS ${OPENSSL_INCLUDE_DIR})
        list(APPEND DXIRCFOX_LIBS ${OPENSSL_LIBRARIES})
        set(HAVE_OPENSSL TRUE)
    endif()
endif()

if(HAVE_LUA)
    list(APPEND DXIRCFOX_INCLUDE_DIRS ${LUA_INCLUDE_DIR})
    list(APPEND DXIRCFOX_LIBS ${LUA_LIBRARIES})
endif(HAVE_LUA)

set(HAVE_ENCHANT FALSE)
set(HAVE_ENCHANT2 FALSE)
if(USE_ENCHANT)
    if(PKG_CONFIG_FOUND)
        pkg_check_modules(ENCHANT enchant-2)
        list(APPEND DXIRCFOX_LIBS ${ENCHANT_LIBRARIES})
        list(APPEND DXIRCFOX_INCLUDE_DIRS ${ENCHANT_INCLUDE_DIRS})
        set(HAVE_ENCHANT TRUE)
        if(ENCHANT_VERSION AND ENCHANT_VERSION VERSION_GREATER "1.6")
            set(HAVE_ENCHANT2 TRUE)
        endif()
        if(NOT ENCHANT_FOUND)
            pkg_check_modules(ENCHANT enchant)
            list(APPEND DXIRCFOX_LIBS ${ENCHANT_LIBRARIES})
            list(APPEND DXIRCFOX_INCLUDE_DIRS ${ENCHANT_INCLUDE_DIRS})
            set(HAVE_ENCHANT TRUE)
            if(ENCHANT_VERSION AND ENCHANT_VERSION VERSION_GREATER "1.6")
                set(HAVE_ENCHANT2 TRUE)
            endif()
        endif()
    endif(PKG_CONFIG_FOUND)
    if(NOT ENCHANT_FOUND)
        set(ENCHANT_INCLUDE_DIR "" CACHE PATH "Path to enchant include dir")
        set(ENCHANT_LIBRARY "" CACHE FILEPATH "Filepath to enchant library")
        set(ENCHANT_VERSION "" CACHE STRING "Enchant verison")
        if(ENCHANT_INCLUDE_DIR)
            list(APPEND DXIRCFOX_LIBS ${ENCHANT_LIBRARY})
            list(APPEND DXIRCFOX_INCLUDE_DIRS ${ENCHANT_INCLUDE_DIR})
            set(HAVE_ENCHANT TRUE)
            if(ENCHANT_VERSION AND ENCHANT_VERSION VERSION_GREATER "1.6")
                set(HAVE_ENCHANT2 TRUE)
            endif()
        else()
            set(HAVE_ENCHANT FALSE)
        endif()
    endif()
endif(USE_ENCHANT)

set(ENABLE_IPV6 ${FOX_ENABLE_IPV6})
set(HAVE_TRAY ${FOX_HAVE_TRAY})
configure_file(config.h.cmake
               ${CMAKE_CURRENT_BINARY_DIR}/config.h
)
list(APPEND DXIRCFOX_INCLUDE_DIRS ${CMAKE_CURRENT_BINARY_DIR})

add_definitions(-DHAVE_CONFIG_H)
if(WIN32)
add_definitions(-DWIN32)
if(NOT FOX_STATIC)
add_definitions(-DFOXDLL)
endif(NOT FOX_STATIC)
add_definitions(-DUNICODE)
add_definitions(-D_UNICODE)
endif(WIN32)

set(SOURCES
dxirc.cpp
dxmessagechannel.cpp
dxpipe.cpp
dxtext.cpp
dxtextfield.cpp
dxutils.cpp
fxext.cpp
icons.cpp
logthread.cpp
preferences.cpp
dialogs/aboutdialog.cpp
dialogs/aliasdialog.cpp
dialogs/configdialog.cpp
dialogs/dccdialog.cpp
dialogs/helpdialog.cpp
dialogs/keybindingsdialog.cpp
dialogs/logviewer.cpp
dialogs/scriptdialog.cpp
dialogs/serverdialog.cpp
dialogs/listdialog.cpp
tabitems/dcctabitem.cpp
tabitems/dxtabbook.cpp
tabitems/dxtabitem.cpp
tabitems/irctabitem.cpp
tabitems/tetristabitem.cpp
tabitems/boatstabitem.cpp
engine/dccengine.cpp
engine/dxsocket.cpp
engine/ircengine.cpp
emojis/emojis.cpp
emojis/dxemoji.cpp
emojis/emojisdialog.cpp
)

set(TRAY_SOURCES
FXTrayApp.cpp
FXTrayIcon.cpp
)

include_directories(${DXIRCFOX_INCLUDE_DIRS}
 ${CMAKE_CURRENT_SOURCE_DIR}
 ${CMAKE_CURRENT_BINARY_DIR}
 ${CMAKE_BINARY_DIR}
)

# pkg-config *_LIBRARIES are bare names (-lFOX-1.6), libs outside default paths (Homebrew) need their dirs
# fox.pc has no -L in Libs, so FOX_LIBRARY_DIRS is empty there, use its libdir
link_directories(${FOX_LIBRARY_DIRS} ${FOX_LIBDIR} ${X11_LIBRARY_DIRS} ${XFT_LIBRARY_DIRS} ${DBUS_LIBRARY_DIRS} ${ENCHANT_LIBRARY_DIRS})

if(FOX_HAVE_TRAY)
 set(SRCS ${SOURCES} ${TRAY_SOURCES})
else(FOX_HAVE_TRAY)
 set(SRCS ${SOURCES})
endif(FOX_HAVE_TRAY)

if(WIN32)
list(APPEND DXIRCFOX_LIBS ws2_32)
list(APPEND DXIRCFOX_LIBS winmm)
endif(WIN32)

if(MINGW)
    # resource compilation for MinGW
    add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/windxirc.o
                    COMMAND ${CMAKE_RC_COMPILER} -I${CMAKE_CURRENT_SOURCE_DIR} -i${CMAKE_CURRENT_SOURCE_DIR}/dxirc-fox.rc
                    -o ${CMAKE_CURRENT_BINARY_DIR}/windxirc.o )
    set(SRCS ${SRCS} ${CMAKE_CURRENT_BINARY_DIR}/windxirc.o)
else(MINGW)
    set(SRCS ${SRCS} dxirc-fox.rc)
endif(MINGW)

ADD_EXECUTABLE(dxirc-fox ${SRCS})
if(WIN32)
    target_link_libraries(dxirc-fox "-Wl,--subsystem,windows -mwindows" ${DXIRCFOX_LIBS})
else(WIN32)
    target_link_libraries(dxirc-fox ${DXIRCFOX_LIBS})
endif(WIN32)

install(TARGETS dxirc-fox DESTINATION bin)

if(DXIRC_BUILD_TESTS)
    if(NOT UNIX OR APPLE)
        message(FATAL_ERROR "Fox tests are supported on Linux only")
    endif()
    # whole application without main(), engine reads preferences from dxirc main window
    list(FILTER SRCS EXCLUDE REGEX "\\.rc$")
    add_library(dxirc-fox-testlib STATIC ${SRCS})
    target_compile_definitions(dxirc-fox-testlib PRIVATE main=dxirc_main)
    target_link_libraries(dxirc-fox-testlib ${DXIRCFOX_LIBS})
    add_executable(ircengine-fox-test ../tests/fox/testutil.cpp ../tests/fox/ircengine_test.cpp)
    target_link_libraries(ircengine-fox-test dxirc-fox-testlib)
    # tests/fox/run.sh: temporary HOME, xvfb-run without display
    add_test(NAME fox-ircengine COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/../tests/fox/run.sh $<TARGET_FILE:ircengine-fox-test>)
    set_tests_properties(fox-ircengine PROPERTIES TIMEOUT 120)
    add_executable(fuzz-fox-test ../tests/fox/testutil.cpp ../tests/fox/fuzz_test.cpp)
    target_link_libraries(fuzz-fox-test dxirc-fox-testlib)
    add_test(NAME fox-fuzz COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/../tests/fox/run.sh $<TARGET_FILE:fuzz-fox-test>)
    set_tests_properties(fox-fuzz PROPERTIES TIMEOUT 300)
    add_executable(versioncheck-fox-test ../tests/fox/testutil.cpp ../tests/fox/versioncheck_test.cpp)
    target_link_libraries(versioncheck-fox-test dxirc-fox-testlib)
    add_test(NAME fox-versioncheck COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/../tests/fox/run.sh $<TARGET_FILE:versioncheck-fox-test>)
    set_tests_properties(fox-versioncheck PROPERTIES TIMEOUT 60)
    add_executable(dxtext-fox-test ../tests/fox/testutil.cpp ../tests/fox/dxtext_test.cpp)
    target_link_libraries(dxtext-fox-test dxirc-fox-testlib)
    add_test(NAME fox-dxtext COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/../tests/fox/run.sh $<TARGET_FILE:dxtext-fox-test>)
    set_tests_properties(fox-dxtext PROPERTIES TIMEOUT 60)
    add_executable(dcc-fox-test ../tests/fox/testutil.cpp ../tests/fox/dcc_test.cpp)
    target_link_libraries(dcc-fox-test dxirc-fox-testlib)
    add_test(NAME fox-dcc COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/../tests/fox/run.sh $<TARGET_FILE:dcc-fox-test>)
    set_tests_properties(fox-dcc PROPERTIES TIMEOUT 120)
    if(HAVE_OPENSSL)
        add_executable(dxsocket-fox-test ../tests/fox/testutil.cpp ../tests/fox/dxsocket_test.cpp)
        target_link_libraries(dxsocket-fox-test dxirc-fox-testlib)
        add_test(NAME fox-dxsocket COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/../tests/fox/run.sh $<TARGET_FILE:dxsocket-fox-test>)
        set_tests_properties(fox-dxsocket PROPERTIES TIMEOUT 60)
    endif()
endif()

message(STATUS "dxirc-fox")
message(STATUS "Install prefix:                             ${CMAKE_INSTALL_PREFIX}")
message(STATUS "Build with IPv6:                            ${FOX_ENABLE_IPV6}")
message(STATUS "Build with tray support:                    ${FOX_HAVE_TRAY}")
message(STATUS "Build with StatusNotifierItem tray:         ${HAVE_DBUS}")
if(HAVE_LUA)
message(STATUS "Build with lua scripting support:           ${HAVE_LUA}/${LUA_VERSION_STRING}")
else(HAVE_LUA)
message(STATUS "Build with lua scripting support:           ${HAVE_LUA}")
endif(HAVE_LUA)
message(STATUS "Build with SSL:                             ${HAVE_OPENSSL}")
if(HAVE_ENCHANT)
message(STATUS "Build with spellchecking support:           ${HAVE_ENCHANT}/${ENCHANT_VERSION}")
else(HAVE_ENCHANT)
message(STATUS "Build with spellchecking support:           ${HAVE_ENCHANT}")
endif(HAVE_ENCHANT)

