İçerikler
Dizin 🔎︎

# MkDir İfadesi

Veri ortamında yeni bir dizin yaratır.

### Sözdizimi:

    MkDir path

### Parametreler:

path: Any string expression that specifies the name and path of the directory to be created. You can also use URL notation.

Yol belirlenmediğinde, dizin mevcut dizin içinde oluşturulur.

### Hata kodları:

5 Geçersiz yordam çağrısı

76 Yol bulunamadı

### Örnek:

    Sub ExampleFileIO
    ' Dosya organizasyonunun fonksiyonları için örnek
    Const sFile1 As String = "file://c|/autoexec.bat"
    Const sDir1 As String = "file://c|/Temp"
    Const sSubDir1 as String ="Test"
    Const sFile2 as String = "Kopyalanmış.tmp"
    Const sFile3 as String = "Renamed.tmp"
    Dim sFile As String
        sFile = sDir1 + "/" + sSubDir1
        ChDir( sDir1 )
        If Dir(sSubDir1,16)="" then ' Dizin var mı ?
            MkDir sSubDir1
            MsgBox sFile,0,"Dizin yarat"
        End If
        sFile = sFile + "/" + sFile2
        FileCopy sFile1 , sFile
        MsgBox fSysURL(CurDir()),0,"Geçerli dizin"
        MsgBox sFile & Chr(13) & FileDateTime( sFile ),0,"Yaratılma zamanı"
        MsgBox sFile & Chr(13)& FileLen( sFile ),0,"Dosya uzunlugu"
        MsgBox sFile & Chr(13)& GetAttr( sFile ),0,"Dosya öznitelikleri"
        Name sFile As sDir1 + "/" + sSubDir1 + "/" + sFile3
        ' Aynı dizini yeniden adlandır
        sFile = sDir1 + "/" + sSubDir1 + "/" + sFile3
        SetAttr( sFile, 0 ) 'Bütün özellikleri sil
        MsgBox sFile & Chr(13) & GetAttr( sFile ),0,"Yeni dosya öznitelikleri"
        Kill sFile
        RmDir sDir1 + "/" + sSubDir1
    End Sub

    ' URL'deki sistem yolunu dönüştürür
    Function fSysURL( fSysFp As String ) As String
    Dim iPos As String
        iPos = 1
        iPos = Instr(iPos,fSysFp, getPathSeparator())
        Do While iPos > 0
            Mid( fSysFp, iPos , 1,"/")
            iPos = Instr(iPos+1,fSysFp, getPathSeparator())
        Loop
        ' iki nokta ile DOS
        iPos = Instr(1,fSysFp,":")
        If iPos > 0 Then Mid( fSysFp, iPos , 1,"|")
        fSysURL = "file://" & fSysFp
    End Function